   5 REM THIS IS A SPECTRUM PROGRAM FOR HELP IN SPECULATOR TRANSFERS IT WILL ***NOT*** RUN ON THE EINSTEIN.
  50 CLS
 100 CLEAR 32499
 150 FOR Z=32500 TO 32509: READ Y: POKE Z,Y: NEXT Z
 200 DATA 175,55,221,33,08,127,205,86,5,201
 250 LET Y=32520: DEF FN Z(A)=PEEK (Y+A)+256*PEEK (Y+A+1)
 300 RANDOMISE USR 32500
 350 LET X=PEEK Y
 400 IF X>3 THEN GO TO 300
 450 PRINT "FILENAME: ";
 500 FOR Z=Y+1 TO Y+10: PRINT CHR$ PEEK Z;: NEXT Z
 550 PRINT : PRINT "TYPE    : ";
 600 GOSUB 1000+100*X
 650 PRINT : PRINT
 700 POKE Y,255
 750 GOTO 300
1000 PRINT "PROGRAM"
1010 PRINT "TOTAL LENGTH: ";FN Z(11);" BYTES"
1020 PRINT "PROG. LENGTH: ";FN Z(15);" BYTES"
1030 IF FN Z(13)>9999 THEN PRINT "LOAD ONLY": RETURN
1040 PRINT "RUNS FROM LINE ";FN Z(13)
1050 RETURN
1100 PRINT "NUMBER ARRAY"
1110 LET A$="": GO TO 1220
1200 PRINT "CHR... ARRAY"
1210 LET A$="$"
1220 PRINT "ARRAY LENGTH: ";FN Z(11);" BYTES"
1230 LET W=PEEK (Y+14)
1240 PRINT "ORIG. ARRAY NAME: ";CHR$ (64+32*(W/32-INT (W/32)));A$
1250 RETURN
1300 IF FN Z(11)=6912 AND FN Z(13)=16384 THEN PRINT "SCREEN STR$": RETURN
1310 PRINT "BYTES"
1320 PRINT "START ADDRESS: ";FN Z(13)
1330 PRINT "LENGTH: ";FN Z(11);" BYTES"
1340 RETURN
